// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/ALU.hdl

/**
 * The ALU (Arithmetic Logic Unit).
 * Computes one of the following functions:
 * x+y, x-y, y-x, 0, 1, -1, x, y, -x, -y, !x, !y,
 * x+1, y+1, x-1, y-1, x&y, x|y on two 16-bit inputs, 
 * according to 6 input bits denoted zx,nx,zy,ny,f,no.
 * In addition, the ALU computes two 1-bit outputs:
 * if the ALU output == 0, zr is set to 1; otherwise zr is set to 0;
 * if the ALU output < 0, ng is set to 1; otherwise ng is set to 0.
 */

// Implementation: the ALU logic manipulates the x and y inputs
// and operates on the resulting values, as follows:
// if (zx == 1) set x = 0        // 16-bit constant
// if (nx == 1) set x = !x       // bitwise not
// if (zy == 1) set y = 0        // 16-bit constant
// if (ny == 1) set y = !y       // bitwise not
// if (f == 1)  set out = x + y  // integer 2's complement addition
// if (f == 0)  set out = x & y  // bitwise and
// if (no == 1) set out = !out   // bitwise not
// if (out == 0) set zr = 1
// if (out < 0) set ng = 1

CHIP ALU {
    IN  
        x[16], y[16],  // 16-bit inputs        
        zx, // zero the x input?
        nx, // negate the x input?
        zy, // zero the y input?
        ny, // negate the y input?
        f,  // compute out = x + y (if 1) or x & y (if 0)
        no; // negate the out output?

    OUT 
        out[16], // 16-bit output
        zr, // 1 if (out == 0), 0 otherwise
        ng; // 1 if (out < 0),  0 otherwise

    PARTS:
    Mux16(a=x, b=false, sel=zx, out=xz);
    Not16(in=xz, out=ntxz);
    Mux16(a=xz, b=ntxz, sel=nx, out=ngx);

    Mux16(a=y, b=false, sel=zy, out=yz);
    Not16(in=yz, out=ntyz);
    Mux16(a=yz, b=ntyz, sel=ny, out=nyx);

    Add16(a=ngx, b=nyx, out=add);
    And16(a=ngx, b=nyx, out=and);
    Mux16(a=and, b=add, sel=f, out=alm);

    Not16(in=alm, out=almn);
    Mux16(a=alm, b=almn, sel=no, out[0..7]=fin1, out[8..15]=fin2, out[15]=ng, out=fin);

    Or8Way(in=fin1, out=has1);
    Or8Way(in=fin2, out=has2);
    Or(a=has1, b=has2, out=nzr);
    Not(in=nzr, out=zr);

    And16(a=true, b=fin, out=out);
}